Mathematica в действии, блог Осипова Романа

Продвинутое задание функций или Mathematica на русском языке

Нажмите, чтобы скачать данный пост в виде ноутбука Mathematica...

Общее количество использованных в посте встроенных функций или символов: 138

Список имен используемых встроенных функций и символов в порядке их появления в коде:
SetDelayed (:=) | Pattern (:) | Blank (_) | Sin | Power (^) | List ({...}) | Plus (+) | Times (*, ×) | Pi (π) | Rational | Graphics | RGBColor | EdgeForm | Thickness | Large | Dashing | Small | Disk | ArcSin | Image | RawArray | Rule (->, ->) | ImageSize | Automatic | ColorSpace | Interleaving | True | Set (=) | N | Log | Factorial (!) | Timing | Cos | Integrate (∫) | FullSimplify | Out (%) | Length | Optional (:) | Red | PlotRange | Max | Axes | Circle | Blue | OptionsPattern | OptionValue | Condition (/;) | Greater (>) | Sqrt | LessEqual (<=, ≤) | Names | PatternTest (?) | PrimeQ | Framed | Table | Alternatives (|) | Integer | I (i) | Mean | Real | Complex | Re | Im | ImageMeasurements | Less (<) | Total | String ("...") | Style | Row | Orange | Options | Plot | Function (&) | Slot (#) | AspectRatio | GoldenRatio | AxesLabel | None | AxesOrigin | AxesStyle | Background | ClippingStyle | ColorFunction | ColorFunctionScaling | Epilog | Exclusions | ExclusionsStyle | Filling | FillingStyle | Frame | False | FrameLabel | FrameStyle | FrameTicks | FrameTicksStyle | GridLines | GridLinesStyle | LabelStyle | Mesh | MeshFunctions | MeshShading | MeshStyle | PlotLabel | PlotLegends | PlotPoints | Full | PlotStyle | Prolog | RegionFunction | RotateLabel | Ticks | TicksStyle | WorkingPrecision | MachinePrecision | Symbol | NumericQ | CompoundExpression (;) | Thick | Dashed | Cubics | GeneratedParameters | InverseFunctions | MaxExtraConditions | Method | Modulus | Quartics | VerifySolutions | Complexes | Reals | Integers | C | Infinity | Solve | AbsolutePointSize | Point | Line | Equal (==) | ReplaceAll (/.)

Одним из самых важных навыков в работе с системой Mathematica, является задание функций, которые имели бы самый разный вид, и зависели бы от разного количества переменных (от буквально ни одной переменной до бесконечного их количества), при этом некоторые переменные могли бы иметь значения, которые используются по умолчанию, если не вводятся их конкретные значения, другие имели бы вид опций, как у многих встроенных в Mathematica функций, или имели бы строгие ограничения на свой тип...

В данном посте будет показано как программировать в Mathematica на русском языке, а для этого я покажу как создать функции, имена которых задаются кириллицей, соответствующие оригинальным встроенным функциям. При этом вы познакомитесь с тем, как собственно задавать самые разные типы и виды функций.

Создание стандартных функций нескольких переменных

Отсроченное задание функции

Задать стандартную функцию можно с помощью конструкции вида:

В данной конструкции участвуют три крайне важных функции Mathematica, первая — это отсроченное присваивание SetDelayed (в короткой форме имеет вид :=), вторая — шаблонное выражение Blank[] (в короткой форме имеет вид _), третья — шаблон с присвоенным ему именем Pattern[name, object] (в короткой форме имеет вид name:object, или, если шаблонный объект представляет собой просто _, то name_).

Рассмотрим подробнее зачем они нужны и как работают.

Отсроченное присваивание := употребляется в виде:

оно присваивает выражение rhs (сокращение от “right hand side” — справа) в качестве отсроченного значения объекта (символа) lhs (сокращение от “left hand side” — слева), при этом выражение rhs остается в невычисленном виде. Как только в коде встречается объект lhs, он заменяется на выражение rhs, которое после этого вычисляется.

Шаблонное выражение _ употребляется в виде:

оно олицетворяет собой любое выражение, написанное на языке Mathematica. При этом, шаблон _h задает любое выражение, головная часть которого совпадает с h.

Шаблон с присвоенным ему именем name_ употребляется в виде:

он служит для “передачи” объекта внутри используемых функциональных конструкций (правил замен, задании функций и т. п.)

Что ж, суммируя сказанное выше, можно сказать, что стандартное задание функции одной переменной имеет вид:

которое в полной форме (в той, которой его на самом деле “видит” и использует Mathematica) выглядит так:

Задание функции в виде отсроченного присваивания, которое в общем случае имеет вид:

f[pattern]:=lhs

работает следующим образом:

как только Mathematica встречает при вычислении кода функцию с именем f, она проводит сопоставление ее аргумента expr (если она встретила выражение f[expr]) с шаблоном pattern. В том случае, если выражение-аргумент expr удовлетворяют шаблону pattern, то конструкция f[expr] заменяется на выражение lhs, в котором все символы с именем, соответствующем имени шаблонного выражения pattern заменяются на выражение expr, после чего полученная конструкция вычисляется и замещает исходное выражение f[expr].

Понятно, что если используется задание функции вида f[v_]:=lhs[v], то, как было сказано выше, любое выражение expr удовлетворит шаблону v_.

Приведу пример. Зададим функцию, которая вычисляет :

закрыть

function1[x_] := Sin[x^2]

Попробуем вычислить ее значение от разных аргументов:

закрыть

{function1[x], function1[y], function1[1/t + x + y + z], function1[function1[x]], function1[2], function1[Sqrt[Pi/5]]}

Как видно из рассмотренных выше примеров, действительно любой объект (число, символ, картинка) удовлетворяют шаблону x_ и Mathematica легко работает со всеми выражениями, что демонстрирует необычайную гибкость ее языка.

Задание функции многих переменных полностью аналогично. Скажем, зададим функцию 3 переменных:

закрыть

function2[x_, y_, Z_] := (x^2 + y^2)/Z^2 + (x^2 + Z^2)/y^2 + (y^2 + Z^2)/x^2

закрыть

{function2[1, 1, 1], function2[a, 1, 1], function2[1/5, Sqrt[3], Pi]}

Создание функции, которая “помнит” свои вычисленные ранее значения

Если изменить отсроченное задание функции следующим образом:

то однажды вычислив значение в некоторой “точке” (значение при некотором значении аргумента, аргументом может быть не обязательно число и необязательно точка в привычном ее понимании...), функция f будет помнить (правда только в рамках данной сессии Mathematica) это значение (здесь была использована функция Set (в короткой форме имеет вид =), которая позволяет присвоить некоторому символу некоторое значение).

Такое задание функции способно сэкономить массу времени, если вычисление правой части отсроченного присваивания функции занимает много времени, но при этом требует больше памяти.

Пример (время вычисления некоторой команды можно узнать с помощью функции Timing):

закрыть

function3[v_] := function3[v] = N[Log[v!]]

закрыть

Timing[function3[1000000]]

закрыть

Timing[function3[1000000]]

Из примера видно, что однажды вычислив значение функции в точке, при таком задании функции, в следующий раз оно не займет никакого времени.

Внимание! Такое присваивание может сыграть с вами злую шутку. Так как значение функции в данной точке хранится в памяти, оно становится нечувствительным к изменению собственно правой части lhs[v] функции:

закрыть

function4[v_] := function4[v] = Sin[v]

закрыть

function4[10]

закрыть

function4[v_] := function4[v] = Cos[v]

закрыть

{function4[10], function4[11]}

Абсолютное задание функции

В том случае, если использовать вместо функции SetDelayed (:=) функцию Set (=) в задании функции:

то выражение справа lhs[v] будет вычислено сразу, после чего в него будут подставляться значения аргументов функции при встрече в дальнейшем выражения вида f[expr] в коде. Такая форма задания функции способна сэкономить время в том случае, если вычисление выражения lhs[v] трудоемко и по сути не зависит от конкретного значения аргумента v.

Сравним отсроченное и абсолютное задания функций.

Вычисление выражения lhs[v] не зависит от значения v напрямую:

закрыть

function5[a_] := Integrate[Sin[a*x]*Sin[(a + 1)*x], {x, 0, 1}]

закрыть

Timing[{function5[1], function5[2], function5[3]}]

закрыть

function6[a_] = Integrate[Sin[a*x]*Sin[(a + 1)*x], {x, 0, 1}]

Вычисление выражения lhs[v] зависит от значения v напрямую:

закрыть

function7[a_] := Length[a]

закрыть

function7[{1, 2, 3, 4, 5}]

закрыть

function8[a_] = Length[a]

закрыть

function8[{1, 2, 3, 4, 5}]

Из двух примеров выше можно сделать два важных вывода:

Внимание! Абсолютное задание можно использовать только в том случае, если вычисление конструкции lhs[v] не зависит напрямую от переменной v. Если это не так, то ответ может быть не верен.

В случае применения абсолютного задания функций, вы получаете возможность заметно ускорить свои вычисления в ситуации, когда вычисление правой части задания функции не зависит напрямую от аргумента.

Задание функции, некоторые аргументы которой имеют значения по умолчанию

В некоторых ситуациях удобно использовать функции, некоторые переменные которых имели бы значения по умолчанию. Задать такого рода переменную для функции можно с помощью функции Optional, которая употребляется следующим образом:

Зададим функцию, которая строит круг или окружность, при этом по умолчанию центр этого круга (окружности) находится в точке (0, 0), он (она) имеет радиус равный 1, а также имеет красный цвет:

закрыть

function9[form_, x_:0, y_:0, r_:1, color_:Red] := Graphics[{color, form[{x, y}, r]}, PlotRange -> Max[x, y] + r, Axes -> True, ImageSize -> 200]

закрыть

function9[Disk]

закрыть

function9[Circle, 1]

закрыть

function9[Circle, 1, 2]

закрыть

function9[Circle, 1, 2, 1/2]

закрыть

function9[Disk, 1, 2, 1/2, Blue]

Очевидным неудобством работы с такими функциями является то, что если вы хотите использовать много аргументов со значениями по умолчанию, то использовать эти значения у вас получится только в том случае, если они стоят справа от тех аргументов, которым вы придаете какое-то значение. Если же вы меняете какое-то значение по умолчанию на конкретное, то вам придется в обязательном порядке явно указывать и все значения, что стоят левее от него. Таким образом, данное задание очень чувствительно к порядку следования аргументов, а значит переменные со значениями по умолчанию должны располагаться в порядке убыли частоты их использования, если же частота примерно одинакова, то целесообразность задания таких функций резко падает.

Задание функции с опциями

Для того, чтобы избавиться от проблемы, связанной с использованием переменных, которые имеют значения по умолчанию, которая рассматривалась выше, служат функции, которые имеют так называемые опции. Большинство встроенных функции Mathematica имеют те или иные опции.

Для того, чтобы задать опции для некоторой функции, служат встроенные функции OptionsPattern и OptionValue, смысл работы с которыми ясен из следующего примера: реализуем ту же функцию, что и ранее (строящую круг или окружность, с центром по умолчанию в точке (0, 0), радиуса 1, красного цвета), только все значения по умолчанию теперь задаются опциями:

закрыть

function10[form_, OptionsPattern[{x -> 0, y -> 0, r -> 1, color -> Red}]] := Graphics[{OptionValue[color], form[{OptionValue[x], OptionValue[y]}, OptionValue[r]]}, PlotRange -> Max[OptionValue[x], OptionValue[y]] + OptionValue[r], Axes -> True, ImageSize -> 200]

закрыть

function10[Disk]

закрыть

function10[Disk, color -> Blue]

закрыть

function10[Disk, color -> Blue, r -> 2, y -> 3]

закрыть

function10[Circle, r -> Pi/2, x -> Pi, y -> -Pi/2]

Задание функции с наложенными на аргументы условиями

Для того, чтобы наложить на какой-то аргумент функции ограничение, служит функция Condition (имеющая короткую форму /;).

Скажем, создадим функцию, которая вычислялась бы, только если ее аргумент больше 2:

закрыть

function11[x_ /; x > 2] := Sin[x]

закрыть

{function11[0], function11[2], function11[3], function11["строка"], function11[5 - Sqrt[8]]}

Или функцию, которая вычислялась бы, если ее аргумент является списком, состоящим не более чем из 4 элементов:

закрыть

function12[x_List /; Length[x] <= 4] := x^2

закрыть

{function12[2], function12[{2}], function12[{1, 2, a, 4}], function12[{1, 2, a, 4, t}], function12[{}]}

В примере выше также использовался шаблон с указанием головной части выражения List (x_List), который задает любой список.

Такого рода шаблоны могут быть самыми разными:

закрыть

function13[x_Sin] := Cos[x]

закрыть

{function13[Sin[1]], function13[Sin[Sin[222]]], function13[Cos[1]], function13[2], function13[{Sin[1]}]}

Также вы можете пользоваться всевозможными тестовыми функциями, которые проверяют, обладает ли выражение, определенным свойством. Это делается с помощью функции PatternTest (имеющая короткую форму ?), стандартный синтаксис которой выглядит следующим образом:

Все тесты (как видно из кода ниже, их 108) в системе Mathematica это функции, которые оканчиваются на заглавную букву Q:

Скажем, вот так просто можно создать функцию, которая будет работать только с простыми числами:

закрыть

function14[(x_)?PrimeQ] := Framed[x]

закрыть

Table[function14[x], {x, 0, 20}]

Альтернативные шаблоны

В некоторых случаях функция должна работать с выражением, если оно удовлетворяет одному из заданных шаблонов. Реализовать подобную конструкцию можно с помощью функции Alternatives (имеющая короткую форму |).

Ниже представлена функция, аргумент которой может быть либо списком, либо целым числом, большим 4:

закрыть

function15[(x_List) | (x_Integer /; x > 4)] := x^10

закрыть

{function15[{1, 2, 3}], function15[1], function15[10], function15[5.3], function15[1 + 2*I], function15["sss"]}

Множественное задание функций

В Mathematica у вас есть возможность задать определения функции,  которые будут применяться в разных ситуациях. Сделать это можно с помощью применения шаблонов с головными частями выражений, а также с использованием ограничений, наложенных на переменные.

В примере ниже создана функция, которая по разному обрабатывает входные данные в зависимости от их типа:

закрыть

function16[{1, 2, 3, 4, 5, 6}]

закрыть

function16[2]

закрыть

function16[2.1243]

закрыть

function16[1 + 2*I]

Пример - композиция из описанных ранее способов задания функции и ее аргументов

закрыть

function17[{1, 4, 3}]

закрыть

function17[{1, 4, 5}]

закрыть

function17[{1, 4, 1}, 3]

закрыть

function17[{0, 1, -1, 1, 0, 0, -1, 1, -1, -1, 0, -1, 0, 1, 1, -1, 1, -1, 1, -1}, "z", size -> 50, color -> Orange]

Программирование в Mathematica на русском языке

Теперь, когда мы знаем о том, как задаются функции, можно поставить перед собой такую задачу: сделать так, чтобы можно было программировать в Mathematica на русском языке с соблюдением основных парадигм: встроенные функции капитализированы и их названия в точности соответствуют действию, которое они осуществляют.

Для этого, нужно сделать русские аналоги встроенных функций.

Начнем с функции Plot, на русском языке ей будет соответствовать функция График. Синтаксис функции Plot имеет вид:

Ее русский аналог будет полностью аналогичен.

Начнем с того, что узнаем список всех опций функции Plot и их значения по умолчанию, это можно сделать с помощью функции  Options:

закрыть

Options[Plot]

Теперь создадим этот список на русском языке (здесь опущены некоторые опции, которые, по опыту, употребляются крайне редко при построении графика):

закрыть

{СоотношениеСторон -> 1/ЗолотоеСечение, Оси -> Да, ПодписиОсей -> Никакой, ПересечениеОсей -> Авто, СтильОсей -> {}, Фон -> Никакой, СтильОбрезки -> Никакой, ЦветоваяФункция -> Авто, МасштабированиеЦветовойФункции -> Да, Эпилог -> {}, Исключения -> Авто, СтильИсключений -> Никакой, Заливка -> Никакой, СтильЗаливки -> Авто, Рамка -> Нет, ПодписиРамки -> Никакой, СтильРамки -> {}, ЗасечкиРамки -> Авто, СтильЗасечекРамки -> {}, ЛинииСетки -> Никакой, СтильЛинийСетки -> {}, РазмерИзображения -> Авто, СтильПодписи -> {}, Сетка -> Никакой, ФункцииСетки -> {#1 & }, ЗатенениеСетки -> Никакой, СтильСетки -> Авто, ПодписьГрафика -> Никакой, ЛегендыГрафика -> Никакой, КоличествоТочек -> Авто, ДиапазонОтображения -> {Полностью, Авто}, СтильГрафика -> Авто, Пролог -> {}, ФункцияОбласти -> (Да & ), ВращатьПодпись -> Да, Засечки -> Авто, СтильЗасечек -> {}, РабочаяОтносительнаяТочность -> МашиннаяТочность}

Теперь зададим связь русских названий с встроенными аналогами:

закрыть

{СоотношениеСторон = AspectRatio, ЗолотоеСечение = GoldenRatio, Оси = Axes, Да = True, ПодписиОсей = AxesLabel, Никакой = None, ПересечениеОсей = AxesOrigin, Авто = Automatic, СтильОсей = AxesStyle, Фон = Background, СтильОбрезки = ClippingStyle, ЦветоваяФункция = ColorFunction, МасштабированиеЦветовойФункции = ColorFunctionScaling, Эпилог = Epilog, Исключения = Exclusions, СтильИсключений = ExclusionsStyle, Заливка = Filling, СтильЗаливки = FillingStyle, Рамка = Frame, Нет = False, ПодписиРамки = FrameLabel, СтильРамки = FrameStyle, ЗасечкиРамки = FrameTicks, СтильЗасечекРамки = FrameTicksStyle, ЛинииСетки = GridLines, СтильЛинийСетки = GridLinesStyle, РазмерИзображения = ImageSize, СтильПодписи = LabelStyle, Сетка = Mesh, ФункцииСетки = MeshFunctions, ЗатенениеСетки = MeshShading, СтильСетки = MeshStyle, ПодписьГрафика = PlotLabel, ЛегендыГрафика = PlotLegends, КоличествоТочек = PlotPoints, ДиапазонОтображения = PlotRange, Полностью = Full, СтильГрафика = PlotStyle, Пролог = Prolog, ФункцияОбласти = RegionFunction, ВращатьПодпись = RotateLabel, Засечки = Ticks, СтильЗасечек = TicksStyle, РабочаяОтносительнаяТочность = WorkingPrecision, МашиннаяТочность = MachinePrecision}

Теперь мы можем задать русский аналог функции Plot:

закрыть

График[p_, {x_Symbol, (xmin_)?NumericQ, (xmax_)?NumericQ}, OptionsPattern[{СоотношениеСторон -> 1/ЗолотоеСечение, Оси -> Да, ПодписиОсей -> Никакой, ПересечениеОсей -> Авто, СтильОсей -> {}, Фон -> Никакой, СтильОбрезки -> Никакой, ЦветоваяФункция -> Авто, МасштабированиеЦветовойФункции -> Да, Эпилог -> {}, Исключения -> Авто, СтильИсключений -> Никакой, Заливка -> Никакой, СтильЗаливки -> Авто, Рамка -> Нет, ПодписиРамки -> Никакой, СтильРамки -> {}, ЗасечкиРамки -> Авто, СтильЗасечекРамки -> {}, ЛинииСетки -> Никакой, СтильЛинийСетки -> {}, РазмерИзображения -> Авто, СтильПодписи -> {}, Сетка -> Никакой, ФункцииСетки -> {#1 & }, ЗатенениеСетки -> Никакой, СтильСетки -> Авто, ПодписьГрафика -> Никакой, ЛегендыГрафика -> Никакой, КоличествоТочек -> Авто, ДиапазонОтображения -> {Полностью, Авто}, СтильГрафика -> Авто, Пролог -> {}, ФункцияОбласти -> (Да & ), ВращатьПодпись -> Да, Засечки -> Авто, СтильЗасечек -> {}, РабочаяОтносительнаяТочность -> МашиннаяТочность}]] := Plot[p, {x, xmin, xmax}, AspectRatio -> OptionValue[СоотношениеСторон], Axes -> OptionValue[Оси], AxesLabel -> OptionValue[ПодписиОсей], AxesOrigin -> OptionValue[ПересечениеОсей], AxesStyle -> OptionValue[СтильОсей], Background -> OptionValue[Фон], ClippingStyle -> OptionValue[СтильОбрезки], ColorFunction -> OptionValue[ЦветоваяФункция], ColorFunctionScaling -> OptionValue[МасштабированиеЦветовойФункции], Epilog -> OptionValue[Эпилог], Exclusions -> OptionValue[Исключения], ExclusionsStyle -> OptionValue[СтильИсключений], Filling -> OptionValue[Заливка], FillingStyle -> OptionValue[СтильЗаливки], Frame -> OptionValue[Рамка], FrameLabel -> OptionValue[ПодписиРамки], FrameStyle -> OptionValue[СтильРамки], FrameTicks -> OptionValue[ЗасечкиРамки], FrameTicksStyle -> OptionValue[СтильЗасечекРамки], GridLines -> OptionValue[ЛинииСетки], GridLinesStyle -> OptionValue[СтильЛинийСетки], ImageSize -> OptionValue[РазмерИзображения], LabelStyle -> OptionValue[СтильПодписи], Mesh -> OptionValue[Сетка], MeshFunctions -> OptionValue[ФункцииСетки], MeshShading -> OptionValue[ЗатенениеСетки], MeshStyle -> OptionValue[СтильСетки], PlotLabel -> OptionValue[ПодписьГрафика], PlotLegends -> OptionValue[ЛегендыГрафика], PlotPoints -> OptionValue[КоличествоТочек], PlotRange -> OptionValue[ДиапазонОтображения], PlotStyle -> OptionValue[СтильГрафика], Prolog -> OptionValue[Пролог], RegionFunction -> OptionValue[ФункцияОбласти], RotateLabel -> OptionValue[ВращатьПодпись], Ticks -> OptionValue[Засечки], TicksStyle -> OptionValue[СтильЗасечек], WorkingPrecision -> OptionValue[РабочаяОтносительнаяТочность]]

Также нам потребуются некоторые стандартные обозначения толщины и цвета линий:

закрыть

Жирный = Thick; Красный = Red; Синий = Blue; Оранжевый = Orange; Пунктир = Dashed;

Аналогично зададим функцию Решить — русский аналог функции Solve, АбсолютныйРазмерТочки — AbsolutePointSize,  Точка — Point, Линия — Line:

Попробуем создать некоторый график:

Таким образом, в Mathematica возможно создать пакет, который позволит программировать на обычном русском языке, подобно тому, как это делалось в СССР, скажем на языке АЛМИР-65.

Если у кого-то из вас появится желание развить данную идею, то вполне возможно сделать так, чтобы Mathematica работала на русском языке.

Блог принадлежит “Русскоязычной поддержке Wolfram Mathematica"©
При любом использовании материалов блога, ссылка на блог обязательна.
Создано с помощью Wolfram Mathematica 9